文章目录
大家好，欢迎来到我的博客，给生活来点imprtus。
今天的主题是函数栈帧。
函数栈帧的创建和销毁
本章主题
1：什么是函数栈帧？
2：理解函数栈帧能够解决什么问题？
3：函数栈帧的创建和销毁解析
一：什么是函数栈帧
我们在写C语言代码的时候，经常会把一个独立的功能抽象为函数，所以C程序是以函数为基本单位的。那函数是如何调用的？函数的返回值又是如何待会的？函数参数是如何传递的？这些问题都和函数栈帧有关系。
函数栈帧（stack frame）就是函数调用过程中在程序的调用栈（call stack）所开辟的空间，这些空间是用来存放：
函数参数
函数返回值
临时变量（包括函数的非静态的局部变量以及编译器自动生产的其他临时变量）保存上下文信息（包括在函数调用前后需要保持不变的寄存器）
二：理解函数栈帧能够解决什么问题
理解函数栈帧有什么用呢？
只要理解了函数栈帧的创建和销毁，以下问题就能够很好的理解：
1：局部变量是如何创建的？
2：为什么局部变量不初始化内容是随机的？
3：函数调用时参数时如何传递的？传参的顺序是怎样的？函数的形参和实参分别是怎样实例化的？
4：函数的返回值是如何带会的？
让我们一起走进函数栈帧的创建和销毁的过程中。
三：函数栈帧创建与销毁解析
3.1什么是栈
栈.stack是现代计算机程序里最为重要的概念之一，几乎每一个程序都使用了栈，没有栈就没有函数，没有局部变量，也就没有我们如今看到的所有的计算机语言。
在经典的计算机科学中，栈被定义为一种特殊的容器，用户可以将数据压入栈中（入栈，push），也可以将已经压入栈中的数据弹出（出栈，pop），但是栈这个容器必须遵守一条规则：先入栈的数据后出栈（First In Last Out， FIFO）。
3.2有关寄存器与反汇编指令
相关寄存器：
eax：通用寄存器，保留临时数据，常用于返回值
ebx：通用寄存器，保留临时数据
ebp：栈底寄存器
esp：栈顶寄存器
eip：指令寄存器，保存当前指令的下一条指令的地址
相关汇编指令：
mov：数据转移指令
push：数据入栈，同时esp栈顶寄存器也要发生改变
pop：数据弹出至指定位置，同时esp栈顶寄存器也要发生改变
sub：减法命令
add：加法命令
call：函数调用，1. 压入返回地址 2. 转入目标函数
jump：通过修改eip，转入目标函数，进行调用
ret：恢复返回地址，压入eip，类似pop eip命令
lea(load effective address):加载有效地址
3.3解析函数栈帧的创建和销毁
3.3.1预备知识
1:每一次函数调用，都要为本次函数调用开辟空间，就是函数栈帧的空间。
2.:这块空间的维护是使用了2个寄存器： esp 和 ebp ，这两者都是地址， ebp 记录的是栈底的地址， esp 记录的是栈顶的地址。
如图所示：
3：. 函数栈帧的创建和销毁过程，在不同的编译器上实现的方法大同小异，本次演示以VS20222为例.
3.3.2函数的调用堆栈
演示代码：
#include<stdio.h>
int Add(int x, int y)
{
int z = 0;//创建c变量
z = x + y;//z变量来接收两者的和
return z;//返回z
}
int main()
{
int a = 10;//创建a变量
int b = 20;//创建b变量
int c = 0;
c = Add(a, b);//函数调用
printf("%d\n", c);
return 0;
}
这段代码，如果我们在VS2022编译器上调试，调试进入Add函数后，我们就可以观察到函数的调用堆栈（右击勾选【显示外部代码】）
函数调用堆栈是反馈函数调用逻辑的，那我们可以清晰的观察到， main 函数调用之前，是由invoke_main 函数来调用main函数。
而是谁又去调用了invoke_main函数呢？这里我们就不予讨论了。
那我们可以确定:
invoke_main 函数应该会有自己的栈帧， main 函数和 Add 函数也会维护自己的栈帧，每个函数栈帧都有自己的 ebp 和 esp 来维护栈帧空间。
那接下来我们从main函数的栈帧创建开始讲解：
3.3.3准备环境
为了让我们研究函数栈帧的过程足够清晰，不要太多干扰，我们可以关闭下面的选项，让汇编代码中排除一些编译器附加的代码：
3.3.4转到反汇编
调试到main函数开始执行的第一行，右击鼠标转到反汇编。
009118E0 push ebp
009118E1 mov ebp,esp
009118E3 sub esp,0E4h
009118E9 push ebx
009118EA push esi
009118EB push edi
009118EC lea edi,[ebp-24h]
009118EF mov ecx,9
009118F4 mov eax,0CCCCCCCCh
009118F9 rep stos dword ptr es:[edi]
009118FB mov ecx,offset _4A4FA288_函数栈帧的创建和销毁@c (091C009h)
00911900 call @__CheckForDebuggerJustMyCode@4 (0911334h)
00911905 nop
//main函数中核心代码
int a = 10;
00911906 mov dword ptr [ebp-8],0Ah
int b = 20;
0091190D mov dword ptr [ebp-14h],14h
int c = 0;
00911914 mov dword ptr [ebp-20h],0
c = Add(a, b);
0091191B mov eax,dword ptr [ebp-14h]
0091191E push eax
0091191F mov ecx,dword ptr [ebp-8]
00911922 push ecx
00911923 call _Add (09110B9h)
00911928 add esp,8
0091192B mov dword ptr [ebp-20h],eax
printf("%d\n", c);
0091192E mov eax,dword ptr [ebp-20h]
00911931 push eax
00911932 push offset string "%d\n" (0917B30h)
00911937 call _printf (09110D7h)
0091193C add esp,8
return 0;
0091193F xor eax,eax
3.3.5函数栈帧的创建
1:我们先来讲解一下main函数核心代码之前的代码
009118E0 push ebp //把ebp寄存器中的值进行压栈，此时的ebp中存放的是
invoke_main函数栈帧的ebp
009118E1 mov ebp,esp //move指令会把esp的值存放到ebp中，相当于产生了main函数的
ebp，这个值就是invoke_main函数栈帧的esp
009118E3 sub esp,0E4h /*sub会让esp中的地址减去一个16进制数字0xe4,产生新的
esp，此时的esp是main函数栈帧的esp，此时结合上一条指令的ebp和当前的esp，ebp和esp之间维护
了一个块栈空间，这块栈空间就是为main函数开辟的，就是main函数的栈帧空间，这一段空间中将
存储main函数中的局部变量，临时数据已经调试信息*/
009118E9 push ebx //将寄存器ebx的值压栈，esp-4
009118EA push esi //将寄存器esi的值压栈，esp-4
009118EB push edi //将寄存器edi的值压栈，esp-4
//下面的代码是在初始化main函数的栈帧空间。
//1. 先把ebp-24h的地址，放在edi中
//2. 把9放在ecx中
//3. 把0xCCCCCCCC放在eax中
//4. 将从ebp-0x24h到ebp这一段的内存的每个字节都初始化为0xCC
009118EC lea edi,[ebp-24h]
009118EF mov ecx,9
009118F4 mov eax,0CCCCCCCCh
009118F9 rep stos dword ptr es:[edi]
以下是图解：
main函数栈帧创建好了，main函数就拥有了自己的空间，来看核心代码：
int a = 10;
00911906 mov dword ptr [ebp-8],0Ah //将10存储到ebp-8的地址处，ebp-8的位置其实就
是a变量
int b = 20;
0091190D mov dword ptr [ebp-14h],14h 将20存储到ebp-14h的地址处，ebp-14h的位置
其实是b变量
int c = 0;
00911914 mov dword ptr [ebp-20h],0 //将0存储到ebp-20h的地址处，ebp-20h的位
置其实是c变量
//以上汇编代码表示的变量a,b,ret的创建和初始化，这就是局部的变量的创建和初始化
//其实是局部变量的创建时在局部变量所在函数的栈帧空间中创建的
c = Add(a, b);
0091191B mov eax,dword ptr [ebp-14h] //传递b，将ebp-14h处放的20放在eax寄存器
0091191E push eax
0091191F mov ecx,dword ptr [ebp-8] //传递a，将ebp-8处放的10放在ecx寄存器中
00911922 push ecx
//跳转调用函数
/*call 指令是要执行函数调用逻辑的，在执行call指令之前先会把call指令的下一条指令的地址进行压栈操作
这个操作是为了解决当函数调用结束后要回到call指令的下一条指令的地方，继续往后执行。*/
00911923 call _Add (09110B9h)
00911928 add esp,8
0091192B mov dword ptr [ebp-20h],eax//将eax的值放入ebp-20h这个地址中
printf("%d\n", c);
0091192E mov eax,dword ptr [ebp-20h]//将ebp-20h的值放入eax这个地址中
00911931 push eax//压栈
00911932 push offset string "%d\n" (0917B30h)//压栈
00911937 call _printf (09110D7h)//调用printf函数，与调用add函数执行原理大致一致
0091193C add esp,8
return 0;
以下是图解：
调用add函数：
int Add(int x, int y)
{
00BE1760 push ebp //将main函数栈帧的ebp保存,esp-4
00BE1761 mov ebp,esp //将main函数的esp赋值给新的ebp，ebp现在是Add函数的ebp
00BE1763 sub esp,0CCh //给esp-0xCC，求出Add函数的esp
00BE1769 push ebx
//将ebx的值压栈,esp-4
00BE176A push esi
//将esi的值压栈,esp-4
00BE176B push edi
//将edi的值压栈,esp-4
int z = 0;
00BE176C mov dword ptr [ebp-8],0 //将0放在ebp-8的地址处，其实就是创建z
z = x + y;
//接下来计算的是x+y，结果保存到z中
00BE1773 mov eax,dword ptr [ebp+8] //将ebp+8地址处的数字存储到eax中
00BE1776 add eax,dword ptr [ebp+0Ch] //将ebp+12地址处的数字加到eax寄存中
00BE1779 mov dword ptr [ebp-8],eax //将eax的结果保存到ebp-8的地址处，其实
就是放到z中
return z;
00BE177C mov eax,dword ptr [ebp-8] //将ebp-8地址处的值放在eax中，其实就是
把z的值存储到eax寄存器中，这里是想通过eax寄存器带回计算的结果，做函数的返回值。}
00BE177F pop edi
00BE1780 pop esi
00BE1781 pop ebx
00BE1782 mov esp,ebp
00BE1784 pop ebp
00BE1785 ret
}
代码执行到Add函数的时候，就要开始创建Add函数的栈帧空间了。
在Add函数中创建栈帧的方法和在main函数中是相似的，在栈帧空间的大小上略有差异而已。
1. 将main函数的 ebp 压栈
2. 计算新的 ebp 和 esp
3. 将 ebx ， esi ， edi 寄存器的值保存
4. 计算求和，在计算求和的时候，我们是通过 ebp 中的地址进行偏移访问到了函数调用前压栈进去的参数，这就是形参访问
5. 将求出的和放在 eax 寄存器并准备带回
图片中的 a’ 和 b’ 其实就是 Add 函数的形参 x , y 。这里的分析很好的说明了函数的传参过程，以及函数在进行值传递调用的时候，形参其实是实参的一份拷贝。对形参的修改不会影响实参。
3.3.6函数栈帧的销毁
当函数调用要结束返回的时候，前面创建的函数栈帧也开始销毁。那具体是怎么销毁的呢？我们看一下反汇编代码：
00911941 pop edi//在栈顶弹出一个值，存放到edi中，esp+4
00911942 pop esi//在栈顶弹出一个值，存放到esi中，esp+4
00911943 pop ebx//在栈顶弹出一个值，存放到ebx中，esp+4
00911944 add esp,0E4h
0091194A cmp ebp,esp
0091194C call __RTC_CheckEsp (0911258h)//前面esp-0E4h，这里又加上，并比较esp，ebp
00911951 mov esp,ebp //再将Add函数的ebp的值赋值给esp，相当于回收了Add函数的栈
帧空间
00911953 pop ebp//弹出栈顶的值存放到ebp，栈顶此时的值恰好就是main函数的ebp，esp+4，此时恢复了main函数的栈帧维护，esp指向main函数栈帧的栈顶，ebp指向了main函数栈帧的栈底。
00911954 ret /*ret指令的执行，首先是从栈顶弹出一个值，此时栈顶的值就是call指
令下一条指令的地址，此时esp+4，然后直接跳转到call指令下一条指令的地址处，继续往下执行。*/
因为我每弹出一个指令，esp栈顶的地址都会升高。
四：扩展知识
其实返回对象时内置类型时，一般都是通过寄存器来带回返回值的，返回对象如果时较大的对象时，一般会在主调函数的栈帧中开辟一块空间，然后把这块空间的地址，隐式传递给被调函数，在被调函数中通过地址找到主调函数中预留的空间，将返回值直接保存到主调函数的。具体可以参考《程序员的自我修养》一书的第10章。
到这里我们给大家完整的演示了main函数栈帧的创建，Add函数栈帧的创建和销毁的过程，相信大家已经能够基本理解函数的调用过程，函数传参的方式，也能够回答课件开始处的问题了。
结语
感谢各位读者的认真倾听，欢迎各位读者在评论区积极讨论。
最后，虚心求教，认真学习，成为自己的大山，宝剑锋从磨砺出，梅花自古寒香来。
come on！！！
