这项研究的部分内容包括确定储罐/井中氚的预期衰变率，假设储罐保持完好并且没有氚泄漏到周围的沉积物中。根据这些假设，储罐中的氚浓度要多久才能低于《核电厂放射性液态流出物排放技术要求》（GB 14587-2011）中要求的排放口下游1km处受纳水体中H-3 浓度不能超过100Bq/L的标准？
本例计算了预期的衰减率，并将其与储罐定期进行的实际测量结果进行了对比。
首先创建一个图表，显示随着时间的推移，放射性衰变对其中一个储罐内的氚浓度可能产生的影响。在这个例子中，我们假设初始年份为1995年（储罐装满并封闭的年份），要计算的年数为85年，根据初始测量，假定储罐内氚的初始浓度为260000 Bq/L 。有以下信息：
- 初始浓度N0=260000 Bq/L
- 填满后储罐被密封
- 氚的半衰期t1/2=12.32年
- 氚的衰变常数k=-ln(2)/t1/2
- t=1995年起的年数
- 某一年的浓度N=N0e-kt
iYear = 1995 ;初始年份。
nYR = 85 ;要计算的年数。
decay = (-(ALOG(2))/12.32) ;氚的衰变常数。
iBq = 260000 ;初始氚浓度的估计。
; 三个方程来计算可能的边界条件。
; Bq 是基于假设的初始氚浓度为2.6x10 5 Bq/L计算得到的放射性衰变。
; BqHigh和BqLow是基于初始浓度可能存在的误差计算得到的衰变可能边界条件。
; 误差范围为正负10%。
Bq = (iBq*EXP(decay*FINDGEN(nYR))) ; expected
BqHigh = ((Bq)*1.10)
BqLow = ((Bq)*0.90)
year = (iYear+FINDGEN(nYR))
; 绘制预期衰变和高/低条件。
myPlot = PLOT(year, Bq, $
DIMENSIONS=[800, 550], LINESTYLE=4, $
TITLE="简易的氚源衰变（Bq/L）", $
XTITLE="年份", YTITLE="氚浓度（Bq/L）", $
NAME='预期值', $
font_name = 'Microsoft Yahei')
high = PLOT(year, BqHigh, COLOR='red', $
DIMENSIONS=[800, 550], /OVERPLOT, $
THICK=2, NAME='+10%')
low = PLOT(year, BqLow, COLOR='green', $
DIMENSIONS=[800, 550], /OVERPLOT, $
THICK=2, NAME='-10%')IDL显示：
可以将这些模拟数据与定期在储存罐内测量的观测值对比，以评估边界条件建模的准确程度以及衰减模拟与实际情况的接近程度。我们还将绘制一条代表规定的氚“安全”浓度线（100Bq/L）。
; 准备为“安全”浓度创建一条线。
year = [2040,2060,2080]
safe = [2.7e3,2.7e3,2.7e3]
safePlot = PLOT(year, safe, DIMENSIONS=[800, 550], $
COLOR='spring green', NAME='安全线', $
/OVERPLOT, THICK=2, LINESTYLE=4)
; 绘制观测数据。创建变量
; 观测年份 (obsYear) 和观测浓度 (obsCi)。
obsYear = [1996,1998,2000,2002,2004,2006, $
2008,2010,2012,2013]
obsBq = [279444,277741,272418,270407,263077,260820,$
261263,260374,251925,225011]
myObs = PLOT(obsYear, obsBq, LINESTYLE=4, COLOR='purple', $
THICK=3, /OVERPLOT, NAME='实测值')
; 使用分配给每个图的名称添加图例。
myLegend = LEGEND(TARGET=[myPlot,myObs,high,low,safePlot], /DATA, $
/AUTO_TEXT_COLOR, FONT_SIZE=10, POSITION=[2070,2.5e5] , $
font_name = 'Microsoft Yahei')新的绘图结果如下图所示：
从这个图表中我们可以看出，假设的初始浓度为260000 Bq/L并不完全正确，氚的衰减也没有按预期进行。由于观测浓度与预期浓度有明显的差异，可能需要进一步调查这个特定储存罐的情况。是否在这里存放了比我们最初假设更多的核废料？浓度是否高于预期？在1995年之后是否进行了额外未记录存放？
这些问题的答案也将影响氚污染（氚羽流）未来状态的建模，因为这在一定程度上取决于在储存罐中存放了多少废料以及何时存放的。
仅仅从这个图表上我们也可以看出，假设“预期”线是准确的，那么这个储存罐中的氚浓度在2070年左右才会达到标准中规定的“安全”水平，即100Bq/L。
标签：储罐,浓度,IDL,羽流,Bq,year,衰变,初始 From： https://www.cnblogs.com/enviidl/p/18008549