1 dev_close_window ()
2 read_image (Image, '测量/0.bmp')
3 get_image_size (Image, Width, Height)
4 dev_open_window (0, 0, Width, Height, 'black', WindowHandle)
5
6 dev_display (Image)
7
8 * 绘制直线
9 draw_line (WindowHandle, Row1, Column1, Row2, Column2)
10 gen_region_line (Line1, Row1, Column1, Row2, Column2)
11
12
13 * 根据绘制的直线坐标构建参数对象
14 Line1Param := [Row1, Column1, Row2, Column2]
15
16 * 1.创建计算测量句柄
17 create_metrology_model (MetrologyHandle)
18 * 2.设置测量模型图像的大小，主要是为了提高效率
19 set_metrology_model_image_size (MetrologyHandle, Width, Height)
20 * 3.添加测量模型对象
21 * 参数1：测量句柄
22 * 参数2：要查找的模型类型 可以是 线 圆 椭圆 旋转矩形
23 * 参数3：对应的模型参数
24 * ‘圆形’：类型圆的计量对象的几何形状由其中心（行，列）和半径指定
25 * ‘旋转矩形’：ShapeParam = [行，列，Phi，长度1，长度2]
26 * ‘椭圆’：ShapeParam = [行，列，Phi，Radius1，Radius2]
27 * ‘线’：ShapeParam = [RowBegin，ColumnBegin，RowEnd，ColumnEnd]
28 * 参数4：MeasureLength1 垂直于边界的测量区域的一半长度 半长
29 * 参数5：MeasureLength2 与边界相切的测量区域的一半长度 半宽 vp中的搜索长度类似
30 * 参数6：MeasureSigma Sigma的高斯函数用于平滑 默认值：1.0 类似于过滤一半像素
31 * 参数7：MeasureThreshold 最小边缘幅度 对比度阈值
32 * 参数8：GenParamName 通用参数的名称 默认值： []
33 * 参数9：GenParamValue 通用参数的值 默认值： []
34 * 参数10：索引 创建的计量对象的索引
35 add_metrology_object_generic (MetrologyHandle, 'line', Line1Param, 20, 5, 1, 30, [], [], Index)
36
37 * 参数1：测量句柄
38 * 参数2：Index：指定测量对象，为all时所有计量对象的参数都被设置（‘all’）
39 * 参数3：GenParamName：输入参数名称；默认：‘num_instances’，参考：
40 * 'measure_length1'：区域，垂直于边界的测量区域的一半长度
41 * 'measure_length2'：区域，相切于边界的测量区域的一半长度
42 * 'measure_distance'：区域，两个测量区域中心之间的距离
43 * 'num_measures'：区域,测量区域数
44 * 'measure_sigma'：测量，用于平滑的高斯函数的 Sigma
45 * 'measure_threshold'：测量,最小边缘幅度阈值
46 * 'measure_select'：测量，边缘端点的选择('last'、'first')
47 * 'measure_transition'：测量，方向('all'、'negative'、 'positive')
48 * 'measure_interpolation'：测量，插值类型
49 * 'min_score'：拟合，最小分数
50 * 'num_instances'：拟合，成功拟合实例的最大数量
51 * 'distance_threshold'：拟合，距离阈值
52 * set_metrology_object_param (MetrologyHandle, 'all', 'measure_transition', 'all')
53 * 4.设置测量句柄的参数
54 * 设置找线的极性 由黑到白 由白到黑 all
55 set_metrology_object_param (MetrologyHandle, 'all', 'measure_transition', 'all')
56 * 设置测量区域的个数 卡尺数量
57 set_metrology_object_param (MetrologyHandle, 'all', 'num_measures', 50)
58 * 设置最少多少个点可以拟合成功
59 set_metrology_object_param (MetrologyHandle, 'all', 'num_instances', 30)
60 * 设置平滑系数
61 set_metrology_object_param (MetrologyHandle, 'all', 'measure_sigma', 2)
62 * 半长 卡尺搜索长度
63 set_metrology_object_param (MetrologyHandle, 'all', 'measure_length1', 10)
64 * 半宽 卡尺投影长度
65 set_metrology_object_param (MetrologyHandle, 'all', 'measure_length2', 0.5)
66 * 对比度阈值
67 set_metrology_object_param (MetrologyHandle, 'all', 'measure_threshold', 20)
68 * 设置找线插值方法
69 set_metrology_object_param (MetrologyHandle, 'all', 'measure_interpolation', 'bilinear')
70 * 设置查找到的第一条边还是第二条边
71 set_metrology_object_param (MetrologyHandle, 'all', 'measure_select', 'last')
72 * 设置最小分数
73 set_metrology_object_param (MetrologyHandle, 'all', 'min_score', 0.7)
74 * 5.测量并拟合测量模型中所有计量对象的几何形状
75 apply_metrology_model (Image, MetrologyHandle)
76 * 6.获取测量区域和计量模型的计量对象的边缘位置结果
77 * 参数1：Contours 测量区域的矩形XLD轮廓
78 * 参数2：处理计量模型
79 * 参数3：计量对象的索引 默认值：‘all’
80 * 参数4：Transition 选择浅色/深色或深色/浅色边缘 默认值：‘all’
81 * 参数5、6：输出查找到点的行列坐标
82 get_metrology_object_measures (Contours, MetrologyHandle, 'all', 'all', Row, Column)
83 * 7.把找到的点通过十字叉显示
84 * 为每个输入点（行、列）生成交叉形状的XLD轮廓
85 * Cross（out）：生成XLD轮廓
86 * Row（in）：输入点集的行坐标
87 * Col（in）：输入点集的列坐标，Col元组的个数与Row元组的个数相同
88 * Size（in）：十字形长度，长度大于等于0
89 * Angle（in）：十字形方向
90 gen_cross_contour_xld (Cross, Row, Column, 3, rad(45))
91 * 8.获取计量模型的测量结果
92 * 参数1：测量句柄
93 * 参数2：Index 计量对象的索引
94 * 参数3：Instance 计量对象的实例
95 * 参数4：通用参数的名称 默认值：‘result_type’ 值列表：‘angle_direction’，‘result_type’，‘used_edges’
96 * 如果GenParamName设置为’result_type’，则GenParamValue允许控制计量对象的返回方式和结果。
97 * 可以立即查询查询的计量对象的所有测量参数，可以单独查询特定参数或者可以查询计量对象的分数
98
99 * ‘angle_direction’：该参数确定由拟合产生的角度的旋转方向。
100 * 将参数’angle_direction’设置为’正’，在物体的主轴和坐标系的水平轴之间以数学正方向（逆时针方向）指定角度。
101 * 将参数’angle_direction’设置为’负’，在对象的主轴和坐标系的水平轴之间沿数学负方向（顺时针）指定角度。角度的结果以弧度返回。
102 * ‘used_edges’：
103 * 要查询实际用于拟合度量对象的边缘点，可以选择以下GenParamValue值：
104 * ‘行’：返回用于拟合度量对象的边的行坐标。
105 * ‘列’：返回用于拟合度量对象的边的列坐标。
106 * ‘振幅’：返回用于拟合度量对象的边缘的边缘幅度。
107 * 参数5：泛型参数的值 默认值：‘all_param’
108 * 参数6：结果值
109 get_metrology_object_result (MetrologyHandle, 'all', 'all', 'result_type', 'all_param', Parameter)
110 *获取测量结果里的开始行坐标
111 get_metrology_object_result (MetrologyHandle, 'all', 'all', 'result_type', 'row_begin', RowBegin)
112 *获取测量结果里的开始列坐标
113 get_metrology_object_result (MetrologyHandle, 'all', 'all', 'result_type', 'column_begin', ColBegin)
114 *获取测量结果里的结束行坐标
115 get_metrology_object_result (MetrologyHandle, 'all', 'all', 'result_type', 'row_end', RowEnd)
116 *获取测量结果里的结束列坐标
117 get_metrology_object_result (MetrologyHandle, 'all', 'all', 'result_type', 'column_end', ColEnd)
118
119 * 查询计量对象的结果轮廓
120 * MetrologyHandle 处理计量模型
121 * Index 计量对象的索引 默认值：‘all’ 建议值：‘all’，0,1,2
122 * Instance 计量对象的实例 默认值：‘all’ 建议值：‘all’，0,1,2
123 * Resolution 相邻轮廓点之间的距离 默认值：1.5
124 get_metrology_object_result_contour (Contour, MetrologyHandle, 'all', 'all', 1.5)
125
126 clear_metrology_model (MetrologyHandle)
标签：直线,metrology,MetrologyHandle,object,测量,参数,measure From： https://www.cnblogs.com/Honsen/p/17622854.html