CDS标准视图：ABC标识文本 I_ABCIndicatorText

@EndUserText.label: 'ABC Indicator - Text'
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IABCINDICTEXT'
@AbapCatalog.compiler.compareFilter: true
@Analytics: { dataExtraction.enabled: true }
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
  dataCategory: #TEXT,
  representativeKey: 'ABCIndicator',
  semanticKey:  [ 'ABCIndicator' ],
  usageType: {
    dataClass: #CUSTOMIZING,
    sizeCategory: #S,
    serviceQuality: #A
  }
}

@Metadata.ignorePropagatedAnnotations
@Search.searchable: true
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]


define view I_ABCIndicatorText as select from t370c_t
association[0..1] to I_ABCIndicator as _ABCIndicator on $projection.ABCIndicator = _ABCIndicator.ABCIndicator
association[0..1] to I_Language as _Language on $projection.Language = _Language.Language{

    @ObjectModel.foreignKey.association: '_ABCIndicator'
    @ObjectModel.text.element: ['ABCIndicatorDesc']
    key t370c_t.abckz as ABCIndicator,

    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key t370c_t.spras as Language,

    @Semantics.text: true
    @EndUserText.label: 'ABC Indicator Text'
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8
    @Search.ranking: #HIGH

    cast( t370c_t.abctx as eams_abctx preserving type ) as ABCIndicatorDesc,

    _ABCIndicator,
    _Language
}