CDS标准视图：功能位置信息 I_FunctionalLocationData

@EndUserText.label: 'Functional Location Data'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AbapCatalog.sqlViewName: 'IFUNCTLOCATTR'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl: {
  authorizationCheck: #CHECK,
  privilegedAssociations: ['_Location', '_Address', '_FuncnlLocationHierarchyNode']
}

@ObjectModel: {
  representativeKey: 'FunctionalLocation',
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #L
  },
  supportedCapabilities: [ #EXTRACTION_DATA_SOURCE ]
}

@Analytics: {
  dataCategory: #DIMENSION,
  dataExtraction: {
    enabled: true,
    delta.byElement: {
      name: 'LastChangeDateTime'
    }
  }
}

@Metadata: {
  ignorePropagatedAnnotations,
  allowExtensions
}

define view I_FunctionalLocationData
  as select from I_FunctionalLocation as I_FunctionalLocation
  association [0..1] to I_FunclocationLabelInternal as _PrimaryLabel                 on  $projection.FunctionalLocation             = _PrimaryLabel.FunctionalLocation
                                                                                     and _PrimaryLabel.FuncnlLocLabelIsPrimaryLabel = 'X'
                                                                                     and _PrimaryLabel.FunctionalLocLabelIsActive   = 'X'
  association [0..1] to I_WorkCenterBySemanticKey   as _MainWorkCenterBySemanticKey  on  $projection.MainWorkCenter      = _MainWorkCenterBySemanticKey.WorkCenter
                                                                                     and $projection.MainWorkCenterPlant = _MainWorkCenterBySemanticKey.Plant
  association [0..1] to I_Plant                     as _MainWorkCenterPlant          on  $projection.MainWorkCenterPlant = _MainWorkCenterPlant.Plant
  association [0..1] to I_WorkCenterBySemanticKey   as _WorkCenterBySemanticKey      on  $projection.workcenter      = _WorkCenterBySemanticKey.WorkCenter
                                                                                     and $projection.WorkCenterPlant = _WorkCenterBySemanticKey.Plant
  association [0..1] to I_Plant                     as _WorkCenterPlant              on  $projection.WorkCenterPlant = _WorkCenterPlant.Plant
  association [0..1] to I_WorkCenter                as _MainWorkCenter               on  _MainWorkCenter.WorkCenterInternalID = $projection.MainWorkCenterInternalID
                                                                                     and _MainWorkCenter.WorkCenterTypeCode   = 'A'
  association [0..1] to I_Indicator                 as _FuncnlLocIsMarkedForDeletion on  $projection.FuncnlLocIsMarkedForDeletion = _FuncnlLocIsMarkedForDeletion.IndicatorValue
  association [0..1] to I_FunctionalLocationData    as _SuperiorFunctionalLocation   on  $projection.SuperiorFunctionalLocation = _SuperiorFunctionalLocation.FunctionalLocation
  association[0..1] to I_MaintenancePlanPlant       as _MaintenancePlanPlant         on $projection.MaintenancePlanningPlant = _MaintenancePlanPlant.MaintenancePlanningPlant
  association[0..1] to I_FuncnlLocationHierarchyNode as _FuncnlLocationHierarchyNode on $projection.FunctionalLocation = _FuncnlLocationHierarchyNode.FunctionalLocation
  association [0..1] to I_WBSElementBasicData      as _WBSElementBasicData      on  $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID
  -- Extension, do not expose as association:
  association [0..1] to E_FunctionalLocation        as _FunctionalLocationExtension  on  _FunctionalLocationExtension.FunctionalLocation = $projection.FunctionalLocation
  association [0..*] to I_FunctionalLocationText    as _FunctionalLocationText        on  _FunctionalLocationText.FunctionalLocation = $projection.FunctionalLocation
{
      @ObjectModel.text.association: '_FunctionalLocationText'
      @ObjectModel.hierarchy.association: '_FuncnlLocationHierarchyNode'
  key I_FunctionalLocation.FunctionalLocation,

      /* Fields, as they appeared in InfoObject 0FUNCT_LOC */
      @ObjectModel.foreignKey.association: '_ABCIndicator'
      _LocationAccountAssignment.ABCIndicator,
      @ObjectModel.foreignKey.association: '_Address'
      _LocationAccountAssignment.AddressID,
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
      _LocationAccountAssignment.MasterFixedAsset,
      @ObjectModel.foreignKey.association: '_ConstructionMaterial'
      ConstructionMaterial,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      _LocationAccountAssignment.CompanyCode,
      @ObjectModel.foreignKey.association: '_CostCenter'
      _LocationAccountAssignment.CostCenter,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      _LocationAccountAssignment.ControllingArea,
      OperationStartDate,
      @ObjectModel.foreignKey.association: '_TechnicalObjectType'
      TechnicalObjectType,
      @ObjectModel.foreignKey.association: '_Location'
      _LocationAccountAssignment.AssetLocation,
      @ObjectModel.foreignKey.association: '_MaintenancePlant'
      _LocationAccountAssignment.MaintenancePlant,
      _LocationAccountAssignment.AssetRoom,
      @ObjectModel.foreignKey.association: '_MaintenancePlanPlant'
      MaintenancePlanningPlant,
      @ObjectModel.foreignKey.association: '_PlantSection'
      _LocationAccountAssignment.PlantSection,
      @ObjectModel.foreignKey.association: '_MaintenancePlannerGroup'
      MaintenancePlannerGroup,
      @ObjectModel.foreignKey.association: '_FunctionalLocLabelingSyst'
      _PrimaryLabel.FunctionalLocLabelingSyst,
      _PrimaryLabel.FunctionalLocationLabelName                                                                                                                                                                                                                                                                    as FuncnlLocPrimaryLabelName,
      _PrimaryLabel.FunctionalLocationLabelVersion,
      cast( _LocationAccountAssignment._WBSElementBasicData.WBSElement as ps_posid preserving type )                                                                                                                                                                                                               as WBSElement,
      @ObjectModel.foreignKey.association: '_FunctionalLocationCategory'
      FunctionalLocationCategory,
      @ObjectModel.foreignKey.association: '_MainWorkCenterBySemanticKey'
      cast( I_FunctionalLocation._WorkCenter.WorkCenter as gewrk preserving type )                                                                                                                                                                                                                                 as MainWorkCenter,
      @ObjectModel.foreignKey.association: '_MainWorkCenterPlant'
      cast( I_FunctionalLocation._WorkCenter.Plant as wergw preserving type )                                                                                                                                                                                                                                      as MainWorkCenterPlant,
      @ObjectModel.foreignKey.association: '_SettlementOrder'
      _LocationAccountAssignment.SettlementOrder,
      @ObjectModel.foreignKey.association: '_WorkCenterBySemanticKey'
      _LocationAccountAssignment._WorkCenter.WorkCenter,
      @ObjectModel.foreignKey.association: '_WorkCenterPlant'
      _LocationAccountAssignment._WorkCenter.Plant                                                                                                                                                                                                                                                                 as WorkCenterPlant,
      @ObjectModel.foreignKey.association: '_MainWorkCenter'
      I_FunctionalLocation.WorkCenterInternalID                                                                                                                                                                                                                                                                    as MainWorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_WorkCenter'
      _LocationAccountAssignment.WorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_WorkCenterType'
      _LocationAccountAssignment.WorkCenterTypeCode,

      /* Additional fields */
      // I_FunctionalLocation
      @ObjectModel.hierarchy.association: '_SuperiorFunctionalLocation'
      SuperiorFunctionalLocation,
      @Semantics.systemDate.createdAt: true
      I_FunctionalLocation.CreationDate,
      @Semantics.systemDate.lastChangedAt: true
      I_FunctionalLocation.LastChangeDate,
      AuthorizationGroup,
      @Semantics.systemDateTime.lastChangedAt: true
      I_FunctionalLocation.LastChangeDateTime,

      @ObjectModel.foreignKey.association: '_FuncnlLocIsMarkedForDeletion'
      --@Semantics.booleanIndicator: true
      cast( case when _Status[ StatusCode = 'I0076' and StatusIsInactive = '' ].StatusCode is not null then 'X' else ' ' end as eam_is_deleted preserving type )                                                                                                                                                   as FuncnlLocIsMarkedForDeletion,

      // I_LocationAccountAssignment
      @ObjectModel.foreignKey.association: '_WBSElementBasicData'
      cast( _LocationAccountAssignment.WBSElementInternalID as ps_psp_pnr preserving type ) as WBSElementInternalID,

      //I_LinearAssetManagementData
      cast( cast( I_FunctionalLocation._LinearAssetManagementData.LinearDataStartPoint as abap.dec(11, 3) ) as eaml_start_point )                                                                                                                                                                                      as LinearDataStartPoint,
      cast( cast( I_FunctionalLocation._LinearAssetManagementData.LinearDataEndPoint as abap.dec(11, 3) ) as eaml_end_point )
                                                                                                                                                                                            as LinearDataEndPoint,
      @Semantics.quantity.unitOfMeasure: 'LinearDataUnitOfMeasure'
      I_FunctionalLocation._LinearAssetManagementData.LinearDataLength,
      @Semantics.unitOfMeasure: true
      I_FunctionalLocation._LinearAssetManagementData.LinearDataUnitOfMeasure,

      /* Associations */
      _FunctionalLocationText,
      _FunctionalLocationCategory,
      _ConstructionMaterial,
      _TechnicalObjectType,
      _MaintenancePlannerGroup,
      _MaintenancePlanningPlant,
      _PrimaryLabel._FunctionalLocLabelingSyst,
      _WBSElementBasicData,
      _LocationAccountAssignment._PlantSection,
      _LocationAccountAssignment._Location,
      _LocationAccountAssignment._Address,
      _LocationAccountAssignment._CompanyCode,
      _LocationAccountAssignment._MaintenancePlant,
      _LocationAccountAssignment._MasterFixedAsset,
      _LocationAccountAssignment._ABCIndicator,
      _LocationAccountAssignment._CostCenter,
      _LocationAccountAssignment._ControllingArea,
      _LocationAccountAssignment._SettlementOrder,
      _LocationAccountAssignment._WorkCenter,
      _LocationAccountAssignment._WorkCenterType,

      _MainWorkCenterBySemanticKey,
      _MainWorkCenterPlant,
      _WorkCenterBySemanticKey,
      _WorkCenterPlant,
      _MainWorkCenter,
      _FuncnlLocIsMarkedForDeletion,
      _SuperiorFunctionalLocation,
      _MaintenancePlanPlant,
      _FuncnlLocationHierarchyNode
}