PLC Structured Text Object Oriented Programming

PLC结构化文本（ST）——接口（Interface）

接口定义

接口定义了所有类继承接口时应遵循的语法合同。接口定义了语法合同 "是什么" 部分，派生类定义了语法合同 "怎么做" 部分。
接口定义了属性、方法和事件，这些都是接口的成员。接口只包含了成员的声明。成员的定义是派生类的责任。接口提供了派生类应遵循的标准结构。---C# 接口（Interface）|菜鸟教程

接口特点

• 接口使得实现接口的类或结构在形式上保持一致。---C# 接口（Interface）|菜鸟教程
• 接口本身并不实现任何功能，它只是和声明实现该接口的对象订立一个必须实现哪些行为的契约。---C# 接口（Interface）|菜鸟教程
• 接口可以继承接口，一个接口可以继承多个不同的接口。
• 接口成员默认是Public，也必须是Public。
• 接口变量可以接收实现该接口类型的类的对象。

接口与抽象类区别

• 抽象类在某种程度上与接口类似，但是，它们大多只是用在当只有少数方法由基类声明由派生类实现时。---C# 接口（Interface）|菜鸟教程
• 抽象类不能直接实例化，但允许派生出具体的，具有实际功能的类。---C# 接口（Interface）|菜鸟教程
• 抽象类的成员不一定都是抽象的，但如果有一个类的成员是抽象的，那么这个类一定是抽象类。

Tips : 以上关于接口和抽象定义、特点和区别，在IEC61131-3 PLC编程标准中同样适用。

接口的实现

// 定义一个接口
INTERFACE I_StringBuilder EXTENDS __SYSTEM.IQueryInterface

// 接口的方法 Append
METHOD Append : I_StringBuilder
VAR_INPUT
	sText : STRING;
END_VAR

// 接口的方法 Clear
METHOD Clear : I_StringBuilder
VAR_INPUT
END_VAR

// 接口的方法 ToString
METHOD ToString : STRING
VAR_INPUT
END_VAR

// 功能块 FB_StringBuilder 实现 接口 I_StringBuilder
FUNCTION_BLOCK FB_StringBuilder IMPLEMENTS I_StringBuilder
VAR
	sContent : STRING; // Store temporary strings;
END_VAR

// 添加接口方法的实现 Append
METHOD Append : I_StringBuilder
VAR_INPUT
	sText : STRING;
END_VAR
--------
sContent := CONCAT(STR1 := sContent, STR2 := sText);
Append := THIS^;

// 添加接口方法的实现 Clear
METHOD Clear : I_StringBuilder
VAR_INPUT
END_VAR
--------
sContent := '';
Clear := THIS^;

// 添加接口方法的实现 ToString
METHOD ToString : STRING
VAR_INPUT
END_VAR
--------
ToString := sContent; // return internal content

定义一个接口I_StringBuilder包含三个方法：Append（作用：在字符串后面添加新字符）、Clear（作用：清空当前字符串）、ToString（作用：输出字符串）。
定义一个功能块FB_StringBuilder实现接口I_StringBuilder并给方法添加具体实现细节。

Tips : 示例接口 I_StringBuilder继承了 __SYSTEM.IQueryInterface，其中 __SYSTEM.IQueryInterface 为系统内置接口，无其它成员，主要作用是为了可以做接口与接口的转换或者接口与指针的转换，所以在PLC ST OOP中一般以它作为接口的基类（最小粒度）以此派生。关于 __SYSTEM.IQueryInterface 接口详细用法可查阅官方资料。
1.Codesys运算符__QUERYPOINTER
2.倍福在线帮助系统

使用接口实现Fluent

在Main(PRG)程序中声明FB_StringBuilder，I_StringBuilder两个对象，然后声明sResult1，sResult2用来接收结果。

PROGRAM MAIN
VAR
	// 字符拼接，输出'Hello world'
	fbStringBuilder : FB_StringBuilder;
	iStringBuilder	: I_StringBuilder := fbStringBuilder;
	sResult1 : STRING;
	sResult2 : STRING;
	bTest : BOOL;
END_VAR

接口对象iStringBuilder在初始化时传入的是fbStringBuilder对象。

• 1.使用对象实现Fluent

IF bTest THEN
	// Function Block Instance
	sResult1 := fbStringBuilder.Clear()
							.Append('H')
							.Append('e')
							.Append('l')
							.Append('l')
							.Append('o')
							.Append(' ')
							.Append('W')
							.Append('o')
							.Append('r')
							.Append('l')
							.Append('d')
							.ToString();
	bTest := FALSE;
END_IF

• 2.使用接口实现Fluent

IF bTest THEN
	// Interface 
	sResult2 := iStringBuilder.Clear()
							.Append('H')
							.Append('e')
							.Append('l')
							.Append('l')
							.Append('o')
							.Append(' ')
							.Append('W')
							.Append('o')
							.Append('r')
							.Append('l')
							.Append('d')
							.ToString();
	bTest := FALSE;
END_IF

方法Clear()和Append()返回值是I_StringBuilder接口，因此可以使用“.”访问接口内部定义的成员。
这种编程方式实现的方法不只这一种，还有其它方式也能实现这种效果，后续文章会有详细介绍。

Tips : 作者喜欢称这种编程方式为流式编程或链式编程，老外习惯的叫法为" Fluent "或者" Work Flow "，具体怎么形容看个人喜好吧。

总结

接口（Interface）是引用类型，与IEC61131-3定义的另一种类型（REFERENCE）相似，目前笔者想到的" 引用类型 "在IEC61131-3中只有两个" 接口（INTERFACE） "和" 引用（REFERENCE） "，若还有其它的引用类型，欢迎大神留言讨论。