标签：end boot bss lds start dyn rel 链接

u-boot的链接脚本文件u-boot.lds分析

最新推荐文章于 2023-06-01 07:57:20 发布 Lamar Davis 于 2020-09-14 20:06:12 发布 阅读量749 收藏 10 点赞数 分类专栏： linux 版权 linux 专栏收录该内容 30 篇文章 2 订阅 订阅专栏

u-boot 版本: 2016.03，NXP更改过的版本，正点原子再次更改，详细可参见正点原子的教程。

这里先贴出来链接脚本文件，它的生成过程，可以参考https://blog.csdn.net/xiaoyink/article/details/108508415，里面有简略的提到，这里主要分析此文件的含义，如下：

1.   OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
2.   OUTPUT_ARCH(arm)
3.   ENTRY(_start)
4.   SECTIONS
5.   {
6.   . = 0x00000000;
7.   . = ALIGN(4);
8.   .text :
9.   {
10.   *(.__image_copy_start)
11.   *(.vectors)
12.   arch/arm/cpu/armv7/start.o (.text*)
13.   *(.text*)
14.   }
15.   . = ALIGN(4);
16.   .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
17.   . = ALIGN(4);
18.   .data : {
19.   *(.data*)
20.   }
21.   . = ALIGN(4);
22.   . = .;
23.   . = ALIGN(4);
24.   .u_boot_list : {
25.   KEEP(*(SORT(.u_boot_list*)));
26.   }
27.   . = ALIGN(4);
28.   .image_copy_end :
29.   {
30.   *(.__image_copy_end)
31.   }
32.   .rel_dyn_start :
33.   {
34.   *(.__rel_dyn_start)
35.   }
36.   .rel.dyn : {
37.   *(.rel*)
38.   }
39.   .rel_dyn_end :
40.   {
41.   *(.__rel_dyn_end)
42.   }
43.   .end :
44.   {
45.   *(.__end)
46.   }
47.   _image_binary_end = .;
48.   . = ALIGN(4096);
49.   .mmutable : {
50.   *(.mmutable)
51.   }
52.   .bss_start __rel_dyn_start (OVERLAY) : {
53.   KEEP(*(.__bss_start));
54.   __bss_base = .;
55.   }
56.   .bss __bss_base (OVERLAY) : {
57.   *(.bss*)
58.   . = ALIGN(4);
59.   __bss_limit = .;
60.   }
61.   .bss_end __bss_limit (OVERLAY) : {
62.   KEEP(*(.__bss_end));
63.   }
64.   .dynsym _image_binary_end : { *(.dynsym) }
65.   .dynbss : { *(.dynbss) }
66.   .dynstr : { *(.dynstr*) }
67.   .dynamic : { *(.dynamic*) }
68.   .plt : { *(.plt*) }
69.   .interp : { *(.interp*) }
70.   .gnu.hash : { *(.gnu.hash) }
71.   .gnu : { *(.gnu*) }
72.   .ARM.exidx : { *(.ARM.exidx*) }
73.   .gnu.linkonce.armexidx : { *(.gnu.linkonce.armexidx.*) }
74.   }

第6行，虽然指定了起始地址是0x00000000，但是实际的起始地址是在编译过程中使用 -T 指定的，-Ttext 0x87800000；

第7行：

.text :
 {
  *(.__image_copy_start)
  *(.vectors)
  arch/arm/cpu/armv7/start.o (.text*)
  *(.text*)
 }

里面前两个段是空段，作用可以参考https://blog.csdn.net/xiaoyink/article/details/108348928，接下来是start.o文件中的文本段，在接下来是其他全部的文本段。

中间.data段，.rodata段我就详解了，就是表面意思。

第24行：

 .u_boot_list : {
  KEEP(*(SORT(.u_boot_list*)));
 }

这个段存放的是u-boot中定义的命令行对应的命令，以及实际执行的函数，详细可以参考U_BOOT_CMD宏定义，这个宏定义其实是定义一个全局结构体，并把全局结构体存放在以.u_boot_list开头的段中，最终这些段都如上述汇聚到 .u_boot_list中，结构体中有命令行命令的字符串名字，函数指针，字符串帮助信息等。

第28行：

 .image_copy_end :
 {
  *(.__image_copy_end)
 }

u-boot启动之后会将自己拷贝到DDR物理内存的结尾处，拷贝的内容到这个段结束，这个段其实不占用内存空间，只是为了传递拷贝的结束地址给汇编程序，或者C程序。

第32行：

 .rel_dyn_start :
 {
  *(.__rel_dyn_start)
 }
 .rel.dyn : {
  *(.rel*)
 }
 .rel_dyn_end :
 {
  *(.__rel_dyn_end)
 }
 .end :
 {
  *(.__end)
 }
 _image_binary_end = .;

 

.rel_dyn_start  .rel_dyn_end 也是为了传递地址，不占用空间，这里不详细讲了，主要是.rel.dyn段的作用，其实它和u-boot的相对地址有关系，u-boot中对函数的调用，以及对全局变量的访问都是通过地址偏移来实现的，u-boot在启动之后会调用relocate_code（汇编函数）把自己拷贝到DDR的靠结尾部分，为的是给linux内核腾出空间，这些都依赖于.rel.dyn段来完成，这个段有一个固定的格式，8个字节为一组，高4字节是一个固定的值0x17，表示存储的是全局变量的Label，如果不是0x17则无效。详见：https://blog.csdn.net/xiaoyink/article/details/108590429

.end段表示的是整个镜像的end，这个段也是个空段，接下来定义的地址常量_image_binary_end也是同样的含义，表示整个uboot镜像的结束。

第49行：

 .mmutable : {
  *(.mmutable)
 }

我也没仔细研究，看意思应该是存放mmu页表的。这里不详解了，接下来是我想说的。

第52行：

 .bss_start __rel_dyn_start (OVERLAY) : {
  KEEP(*(.__bss_start));
  __bss_base = .;
 }
 .bss __bss_base (OVERLAY) : {
  *(.bss*)
   . = ALIGN(4);
   __bss_limit = .;
 }
 .bss_end __bss_limit (OVERLAY) : {
  KEEP(*(.__bss_end));
 }

 .bss_start段和 .bss_end段依然是空段，用来传递.bss段的起始地址和结束地址。

但是注意一点，这里 “.bss_start __rel_dyn_start (OVERLAY) :” 这句话里面的__rel_dyn_start 应该是在C文件中定义的数组名，位于.__rel_dyn_start段（这里链接脚本居然可以直接使用C中的数组名，我也是第一次看到，具体格式我就不纠结了，关于链接脚本，C文件以及汇编文件中地址常量的相互引用可以参考：https://blog.csdn.net/xiaoyink/article/details/108348928），我这里就说什么含义OVERLAY的含义应该是.__rel_dyn_start段和.bss段使用同一块内存空间，也就是这两个段在物理地址上是重叠的，可以在u-boot.map文件中求证，这两个段的起始地址确实是一样的。为什么他们要重合，不会出错吗？

其实.__rel_dyn_start段主要是u-boot拷贝自己的时候使用，参考u-boot源码可以发现，u-boot拷贝自己之前，基本上都是汇编语句，即使是调用了C函数也没有使用.bss段内的全局变量，唯一的全局结构体gd（也可能不是唯一的）的地址也是存放在r9寄存器中，所以拷贝之前是用不到.bss段的，但是要用.__rel_dyn_start段，而拷贝之后用不到.__rel_dyn_start段，但是要用.bss段，所以为了节省内存，这两个段是可以重合的。另外拷贝的目的地址处，我们已经为.bss段留出了空间，.bss段是和整个u-boot镜像一起的，gd结构体的mon_len成员（= __bss_end -_start）记录的就是整个u-boot需要占用的内存空间，其中包括了.bss段。

64行之后的几个段，没有具体研究，肯定也不在u-boot拷贝自己的范畴之内。

总结：

u-boot.bin文件 和 实际在内存中 的段 以及几个地址常量的分布如下：

图像对应的visio文件已经备份到如下地址：

https://download.csdn.net/download/xiaoyink/12841945

 

标签：end,boot,bss,lds,start,dyn,rel,链接
From： https://www.cnblogs.com/zxdplay/p/17991619