网络启动（用于调试）
# 设置网络环境变量
setenv ipaddr 192.168.10.50
setenv ethaddr b8:ae:1d:01:00:00
setenv gatewayip 192.168.10.1
setenv netmask 255.255.255.0
setenv serverip 192.168.10.100
# 通过 NFS 挂载根文件系统，前提要将根文件系统放到 Ubuntu 下的 nfs 目录中
setenv netargs_m 'setenv bootargs console=ttymxc0,115200 root=/dev/nfs nfsroot=192.168.10.100:/home/mzq/netdir/nfs/bb_rootfs,v3,proto=tcp rw ip=192.168.10.50:192.168.10.100:192.168.10.1:255.255.255.0::eth0:off'
# 使用 TFTP 从 Ubuntu 中下载 zImage 和设备树文件，前提要将 zImage 和设备树文件放到 Ubuntu 下的 tftp 目录中
setenv netboot_m 'run netargs_m; tftp 80800000 zImage; tftp 83000000 imx6ull-mzq.dtb; bootz 80800000 - 83000000'
setenv bootcmd 'run netboot_m'
saveenv
# 启动 linux
boot
# 或
run bootcmd
emmc 启动（最终方式）
setenv mmcargs_m 'setenv bootargs console=ttymxc0,115200 root=/dev/mmcblk1p2 rootwait rw'
setenv mmcboot_m 'run mmcargs_m; mmc dev 1; fatload mmc 1:1 80800000 zImage; fatload mmc 1:1 83000000 imx6ull-mzq.dtb; bootz 80800000 - 83000000;'
setenv bootcmd 'run mmcboot_m'
saveenv
# 启动 linux
boot
# 或
run bootcmd
nand 启动（最终方式）
setenv nandargs_m 'setenv bootargs console=ttymxc0,115200 root=/dev/mmcblk1p2 rootwait rw'
setenv nandboot_m 'run nandargs_m; nand read 80800000 4000000 800000; nand read 83000000 6000000 100000; bootz 80800000 - 83000000'
setenv bootcmd 'run nandboot_m'
saveenv
# 启动 linux
boot
# 或
run bootcmd