正在学习新1期第14课und异常模式程序示例的同学，可能会发现014_und_exception_014_004\001的代码存在如下BUG，学员在论坛反馈后，我们已经第一时间解决，下面将以对话的形式完整的呈现这个解决方案。
**学员azoxi：**对ARM裸机加强版-第14课 und异常模式有打印异常疑惑，以下是我的start.S 代码(在源码基础上稍作修改)：
.text
.global _start
_start:
b reset /*vector 0 : reset*/
b do_und /*vector 4 : undefined*/
do_und:
/* 执行到这里之前：
* 1. lr_und保存有被中断模式中的下一条即将执行的指令的地址
* 2. SPSR_und保存有被中断模式的CPSR
* 3. CPSR中的M0-M4被设置为11011，进入到und模式
* 4. 跳转到0x4的地址执行程序
*/
/*sp_und 这个模式下的栈还未设置,先设置它*/
ldr sp, =0x34000000
/*保存现场*/
/*在und异常处理函数中有可能会修改r0-r12寄存器的值，所以先保存*/
/*lr是异常处理完后的返回地址，也需要保存*/
stmdb sp!, {r0-r12, lr}
/*处理异常*/
mrs r0, cpsr
ldr r1, =und_string
bl printException
/*恢复现场*/
ldmia sp!, {r0-r12, pc}^ /*^会把spsr的值回复到cpsr中*/
und_string:
.string "undefined instruction exception"
reset:
/* 关闭看门狗 */
ldr r0, =0x53000000
ldr r1, =0
str r1, [r0]
/* 设置MPLL, FCLK : HCLK : PCLK = 400m : 100m : 50m */
/* LOCKTIME(0x4C000000) = 0xFFFFFFFF */
ldr r0, =0x4C000000
ldr r1, =0xFFFFFFFF
str r1, [r0]
/* CLKDIVN(0x4C000014) = 0X5, tFCLK:tHCLK:tPCLK = 1:4:8 */
ldr r0, =0x4C000014
ldr r1, =0x5
str r1, [r0]
/* 设置CPU工作于异步模式 */
mrc p15,0,r0,c1,c0,0
orr r0,r0,#0xc0000000 //R1_nF:OR:R1_iA
mcr p15,0,r0,c1,c0,0
/* 设置MPLLCON(0x4C000004) = (92<<12)|(1<<4)|(1<<0)
* m = MDIV+8 = 92+8=100
* p = PDIV+2 = 1+2 = 3
* s = SDIV = 1
* FCLK = 2*m*Fin/(p*2^s) = 2*100*12/(3*2^1)=400M
*/
ldr r0, =0x4C000004
ldr r1, =(92<<12)|(1<<4)|(1<<0)
str r1, [r0]
/* 一旦设置PLL, 就会锁定lock time直到PLL输出稳定
* 然后CPU工作于新的频率FCLK
*/
/* 设置内存: sp 栈 */
/* 分辨是nor/nand启动
* 写0到0地址, 再读出来
* 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
* 否则就是nor启动
*/
mov r1, #0
ldr r0, [r1] /* 读出原来的值备份 */
str r1, [r1] /* 0->[0] */
ldr r2, [r1] /* r2=[0] */
cmp r1, r2 /* r1==r2? 如果相等表示是NAND启动 */
ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
moveq sp, #4096 /* nand启动 */
streq r0, [r1] /* 恢复原来的值 */
bl sdram_init
bl copy2sdram /*调用c函数copy 参数:src, dest,len*/
bl clean_bss /*调用c函数清楚bss段 参数:start, end*/
bl uart0_init
//bl uart0_init
//bl print1 如果没这条指令，下面的异常测试将不会执行，是不是因为加上了这条指令bin文件刚好不满足前4k？，我就在上面添加两条bl uart0_init ，还是没有输出
这里面很有疑惑，希望能解答。
und_code:
.word 0xdeadc0de /*为了测试arm进入未定义指令模式，插入未定义指令*/
ldr pc, =main /* 绝对跳转，跳到SDRAM */
halt:
b halt我的问题：没有调用bl print1，后面的异常没有任何输出，但是其他串口打印都正常，加上这条就有异常输出，什么原因？
韦东山：这是一个课后作业，也是我的失误引入的一个BUG。
0xdeadc0de 是一条“条件执行命令”，
ARM指令中，bit32-bit28表示执行条件，看下表，0xd表示小于或等于时才执行；
这个条件在上面的bl print1中恰好满足，
所以: 0xdeadc0de 会执行，并且导致und异常。
当把 bl print1去掉后，0xdeadc0de的执行条件不满足，这指令不执行。
解决方法：把 0xdeadc0de 改为0xeeadc0de ，它是无条件执行。
附：s3c2440指令条件码。
技术交流群（鸿蒙开发/Linux/嵌入式/驱动/资料下载）
QQ群：869222007
单片机-嵌入式Linux交流群：
QQ群：536785813
百问科技公众号
百问科技服务号