BZOJ4557-侦察守卫

侦察守卫(observer)

【题目描述】

小R和B神正在玩一款游戏。这款游戏的地图由n个点和n-1条无向边组成，每条无向边连接两个点，且地图是连通的。换句话说，游戏的地图是一棵有n个节点的树。

游戏中有一种道具叫做侦查守卫，当一名玩家在一个点上放置侦查守卫后，它可以监视这个点以及与这个点的距离在d以内的所有点。这里两个点之间的距离定义为它们在树上的距离。在一个点上放置侦查守卫需要付出一定的代价，在不同点放置守卫的代价可能不同。现在小R知道了所有B神可能会出现的位置，请你计算监视所以这些位置的最小代价。 

【输入格式】

第一行两个正整数n和d，分别表示地图上的点数和侦查守卫的视野范围。

第二行n个正整数，第i个正整数表示在编号为i的点放置侦查守卫的代价w[i]。

第三行一个正整数m，表示B神可能出现的点的数量。

第四行m个正整数，分别表示每个B神可能出现的点的编号，从小到大不重复地给出。

接下来n – 1行，每行包含两个正整数u,v，表示在编号为u的点和编号为v的点之间有一条无向边。

【输出格式】

一行一个整数，表示监视所有B神可能出现的点所需要的最小代价。

【输入样例】

12 2

8 9 12 61 1 5 1 4 8 10 6

10

1 2 3 5 67 8 9 10 11

1 3

2 3

3 4

4 5

4 6

4 7

7 8

8 9

9 10

10 11

11 12

【输出样例】

10

【数据范围与约定】

对于100%的数据，n<= 500000，d <= 20，w[i] <=1000，m<= n。

 题解：这是一道典型的树形DP。f[i][j]表示i这棵子树往下j步以下需要覆盖的点全都覆盖的最小代价。g[i][j]表示i这棵子树全都覆盖并且还可以往上覆盖j步的最小代价。ans=f[1][0];并且f[i][0]=g[i][0]。

Code：

var
  vet,next,head,w:array[0..1000005] of longint;
  b:array[0..1000005] of boolean;
  n,d,m,cnt,i,u,v,x:longint;
  f,g:array[0..500005,0..25] of longint;
function min(a,b:longint):longint;
begin
  if a<b then exit(a) else exit(b);
end;
procedure add(u,v:longint);
begin
  inc(cnt);
  vet[cnt]:=v;
  next[cnt]:=head[u];
  head[u]:=cnt;
end;
procedure dfs(x,father:longint);
var i,v,e,j:longint;
begin
  if b[x] then
  begin
    f[x,0]:=w[x];
    g[x,0]:=w[x];
  end;
  for i:=1 to d do g[x,i]:=w[x];
  g[x,d+1]:=1000000000;
  e:=head[x];
  while e>0 do
  begin
    v:=vet[e];
    if v=father then
    begin
      e:=next[e];
      continue;
    end;
    dfs(v,x);
    for j:=d downto 0 do
      g[x,j]:=min(g[x,j]+f[v,j],g[v,j+1]+f[x,j+1]);
    for j:=d downto 0 do g[x,j]:=min(g[x,j],g[x,j+1]);
    f[x,0]:=g[x,0];
    for j:=1 to d+1 do f[x,j]:=f[x,j]+f[v,j-1];
    for j:=1 to d+1 do f[x,j]:=min(f[x,j],f[x,j-1]);
    e:=next[e];
  end;
end;
begin
  assign(input,'observer.in');reset(input);
  assign(output,'observer.out');rewrite(output);
  readln(n,d);
  for i:=1 to n do read(w[i]);
  readln(m);
  for i:=1 to m do
  begin
    read(x);
    b[x]:=true;
  end;
  for i:=1 to n-1 do
  begin
    readln(u,v);
    add(u,v);add(v,u);
  end;
  dfs(1,0);
  writeln(f[1,0]);
  close(input);close(output);
end.