CDS标准视图：维护包描述 I_MaintPackageTextData

@EndUserText.label: 'Maintenance Package - Text'
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'IMNTPCKGTXTDATA'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'MaintenancePackage'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@Metadata.ignorePropagatedAnnotations: true

@Analytics: {
  dataExtraction: {
    enabled: true
  }
}

@ObjectModel.modelingPattern:   #EXTRACTION_DATA_SOURCE
@ObjectModel.supportedCapabilities:     [ #EXTRACTION_DATA_SOURCE ]

define view I_MaintPackageTextData
    as select from I_MaintenancePackageText

    association [0..1] to I_MaintenanceStrategyData as _MaintenanceStrategy     on  _MaintenanceStrategy.MaintenanceStrategy = $projection.MaintenanceStrategy

    association [0..1] to I_MaintenancePackageData  as _MaintenancePackage      on  _MaintenancePackage.MaintenanceStrategy = $projection.MaintenanceStrategy
                                                                                and _MaintenancePackage.MaintenancePackage  = $projection.MaintenancePackage

    association [0..1] to I_Language                as _Language                on  _Language.Language = $projection.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key Language,

      @ObjectModel.foreignKey.association: '_MaintenanceStrategy'
  key MaintenanceStrategy,

      @ObjectModel.foreignKey.association: '_MaintenancePackage'
  key MaintenancePackage,

      @Semantics.text: true
      MaintenancePackageText,

      @Semantics.text: true
      MaintPackageHierarchyShortText,

      @Semantics.text: true
      MaintenanceCycleShortText,

      @Semantics.text: true
      StartOffsetShortText,

      /* Associations - locally defined */
      _Language,
      _MaintenancePackage,
      _MaintenanceStrategy
}