message

Log a message.

Synopsis

General messages
  message([<mode>] "message text" ...)

Reporting checks
  message(<checkState> "message text" ...)

General messages

message([<mode>] "message text" ...)

Record the specified message text in the log. If more than one message string is given, they are concatenated into a single message with no separator between the strings.

The optional <mode> keyword determines the type of message, which influences the way the message is handled:

FATAL_ERROR

CMake Error, stop processing and generation.

SEND_ERROR

CMake Error, continue processing, but skip generation.

WARNING

CMake Warning, continue processing.

AUTHOR_WARNING

CMake Warning (dev), continue processing.

DEPRECATION

CMake Deprecation Error or Warning if variable CMAKE_ERROR_DEPRECATED or CMAKE_WARN_DEPRECATED is enabled, respectively, else no message.

(none) or NOTICE

Important message printed to stderr to attract user’s attention.

STATUS

The main interesting messages that project users might be interested in. Ideally these should be concise, no more than a single line, but still informative.

VERBOSE

Detailed informational messages intended for project users. These messages should provide additional details that won’t be of interest in most cases, but which may be useful to those building the project when they want deeper insight into what’s happening.

DEBUG

Detailed informational messages intended for developers working on the project itself as opposed to users who just want to build it. These messages will not typically be of interest to other users building the project and will often be closely related to internal implementation details.

TRACE

Fine-grained messages with very low-level implementation details. Messages using this log level would normally only be temporary and would expect to be removed before releasing the project, packaging up the files, etc.

The CMake command-line tool displays STATUS to TRACE messages on stdout with the message preceded by two hyphens and a space. All other message types are sent to stderr and are not prefixed with hyphens. The CMake GUI displays all messages in its log area. The curses interface shows STATUS to TRACE messages one at a time on a status line and other messages in an interactive pop-up box. The --log-level command-line option to each of these tools can be used to control which messages will be shown. To make a log level persist between CMake runs, the CMAKE_MESSAGE_LOG_LEVEL variable can be set instead. Note that the command line option takes precedence over the cache variable.

Messages of log levels NOTICE and below will have each line preceded by the content of the CMAKE_MESSAGE_INDENT variable (converted to a single string by concatenating its list items). For STATUS to TRACE messages, this indenting content will be inserted after the hyphens.

Messages of log levels NOTICE and below can also have each line preceded with context of the form [some.context.example]. The content between the square brackets is obtained by converting the CMAKE_MESSAGE_CONTEXT list variable to a dot-separated string. The message context will always appear before any indenting content but after any automatically added leading hyphens. By default, message context is not shown, it has to be explicitly enabled by giving the cmake --log-context command-line option or by setting the CMAKE_MESSAGE_CONTEXT_SHOW variable to true. See the CMAKE_MESSAGE_CONTEXT documentation for usage examples.

CMake Warning and Error message text displays using a simple markup language. Non-indented text is formatted in line-wrapped paragraphs delimited by newlines. Indented text is considered pre-formatted.

function(bar)
  list(APPEND CMAKE_MESSAGE_CONTEXT "bar")
  message(VERBOSE "bar VERBOSE message")
endfunction()

function(baz)
  list(APPEND CMAKE_MESSAGE_CONTEXT "baz")
  message(DEBUG "baz DEBUG message")
endfunction()

function(foo)
  list(APPEND CMAKE_MESSAGE_CONTEXT "foo")
  bar()
  message(TRACE "foo TRACE message")
  baz()
endfunction()

list(APPEND CMAKE_MESSAGE_CONTEXT "top")

message(VERBOSE "Before `foo`")
foo()
message(VERBOSE "After `foo`")

list(POP_BACK CMAKE_MESSAGE_CONTEXT)

-- [top] Before `foo`
-- [top.foo.bar] bar VERBOSE message
-- [top.foo] foo TRACE message
-- [top.foo.baz] baz DEBUG message
-- [top] After `foo`

Reporting checks

A common pattern in CMake output is a message indicating the start of some sort of check, followed by another message reporting the result of that check. For example:

message(STATUS "Looking for someheader.h")
#... do the checks, set checkSuccess with the result
if(checkSuccess)
  message(STATUS "Looking for someheader.h - found")
else()
  message(STATUS "Looking for someheader.h - not found")
endif()

This can be more robustly and conveniently expressed using the CHECK_... keyword form of the message() command:

message(<checkState> "message" ...)

where <checkState> must be one of the following:

CHECK_START

Record a concise message about the check about to be performed.

CHECK_PASS

Record a successful result for a check.

CHECK_FAIL

Record an unsuccessful result for a check.

When recording a check result, the command repeats the message from the most recently started check for which no result has yet been reported, then some separator characters and then the message text provided after the CHECK_PASS or CHECK_FAIL keyword. Check messages are always reported at STATUS log level.

Checks may be nested and every CHECK_START should have exactly one matching CHECK_PASS or CHECK_FAIL. The CMAKE_MESSAGE_INDENT variable can also be used to add indenting to nested checks if desired. For example:

message(CHECK_START "Finding my things")
list(APPEND CMAKE_MESSAGE_INDENT "  ")
unset(missingComponents)

message(CHECK_START "Finding partA")
# ... do check, assume we find A
message(CHECK_PASS "found")

message(CHECK_START "Finding partB")
# ... do check, assume we don't find B
list(APPEND missingComponents B)
message(CHECK_FAIL "not found")

list(POP_BACK CMAKE_MESSAGE_INDENT)
if(missingComponents)
  message(CHECK_FAIL "missing components: ${missingComponents}")
else()
  message(CHECK_PASS "all components found")
endif()

Output from the above would appear something like the following:

-- Finding my things
--   Finding partA
--   Finding partA - found
--   Finding partB
--   Finding partB - not found
-- Finding my things - missing components: B



#######################################################################################################################

#######################################################################################################################

#######################################################################################################################

概要
常规消息
message([<mode>] “消息文本” …)

报告检查
message(<checkState> “消息文本” …)
常规消息
message([<mode>] “消息文本” …)
将指定的消息文本记录在日志中。如果给出了多个消息字符串，则它们将连接成单个消息，字符串之间没有分隔符。

可选的<mode>关键字确定消息的类型，这影响消息的处理方式：

FATAL_ERROR
CMake错误，停止处理和生成。

SEND_ERROR
CMake错误，继续处理，但跳过生成。

WARNING
CMake警告，继续处理。

AUTHOR_WARNING
CMake警告（开发者），继续处理。

DEPRECATION
如果启用了变量CMAKE_ERROR_DEPRECATED或CMAKE_WARN_DEPRECATED，则为CMake废弃错误或警告，否则无消息。

(none) 或 NOTICE
重要消息打印到stderr以吸引用户的注意。

STATUS
项目用户可能感兴趣的主要消息。理想情况下，这些应该简洁，不超过一行，但仍然信息丰富。

VERBOSE
面向项目用户的详细信息消息。这些消息应该提供额外的细节，大多数情况下不会引起兴趣，但对于那些想要深入了解正在发生的事情的构建项目的人可能是有用的。

DEBUG
面向项目本身的开发人员的详细信息消息，而不是仅仅想要构建项目的用户。这些消息通常不会引起其他构建项目的用户的兴趣，并且通常与内部实现细节密切相关。

TRACE
具有非常低级别实现细节的细粒度消息。使用此日志级别的消息通常仅是临时的，并且期望在发布项目、打包文件等之前被删除。

CMake命令行工具会将STATUS到TRACE消息显示在stdout上，并在消息之前添加两个连字符和一个空格。所有其他消息类型都会发送到stderr，并且不会添加连字符。CMake GUI在其日志区域显示所有消息。curses接口在状态行上逐个显示STATUS到TRACE消息，其他消息在交互式弹出框中显示。每个工具的–log-level命令行选项可用于控制将显示哪些消息。要使日志级别在CMake运行之间持久化，可以设置CMAKE_MESSAGE_LOG_LEVEL变量。请注意，命令行选项优先于缓存变量。

消息级别为NOTICE及以下的消息将使每行都以CMAKE_MESSAGE_INDENT变量的内容（通过将其列表项连接为单个字符串）为前缀。对于STATUS到TRACE消息，这个缩进内容将在连字符之后插入。

消息级别为NOTICE及以下的消息也可以以形如[some.context.example]的上下文为前缀。方括号之间的内容通过将CMAKE_MESSAGE_CONTEXT列表变量转换为点分隔的字符串获得。消息上下文将始终出现在任何缩进内容之前，但在任何自动添加的前导连字符之后。默认情况下，消息上下文不会显示，必须通过给出cmake --log-context命令行选项或将CMAKE_MESSAGE_CONTEXT_SHOW变量设置为true来显式启用。有关用法示例，请参阅CMAKE_MESSAGE_CONTEXT文档。

CMake警告和错误消息文本使用简单的标记语言进行格式化。非缩进文本以换行符分隔的段落格式化。缩进的文本被视为预格式化的。