实验十六
题目：
本次实验任务：
安装一个新的int 7CH 中断例程，为显示输出提供如下功能子程序。
（1）清屏；
（2）设置前景色；
（3）设置后景色；
（4）向上滚动一行。
入口参数说明如下。
（1）用ah寄存器传递功能号：0表示清屏，1表示设置前景色，2表示设置背景色，3表示向上滚动一行；
（2）对于1、2号功能，用al传送颜色值，al的值∈{0,1,2,3,4,5,6,7}。
代码如下：
; assume cs:code
; code segment
; start:
; mov ax,cs
; mov ds,ax
; mov si,offset setscreen
; push cs
; pop es
; mov di,offset setscreen
; cld
; mov cx,offset setscreenends-offset setscreen
; rep movsb
; cli
; mov word ptr es:[7ch*4],offset setscreen
; mov word ptr es:[7ch*4+2],cs
; sti
; mov ax,4c00h
; int 21h
; setscreen:
; jmp short set
; table dw sub1,sub2,sub3,sub4
; set:
; push bx
; cmp ah,3
; ja sret
; mov bl,ah
; mov bh,0
; add bx,bx
; call word ptr table[bx]
; sret:
; pop bx
; iret
; sub1:
; push bx
; push cx
; push es
; mov bx,0b800h
; mov es,bx
; mov bx,0
; mov cx,2000
; sub1s:
; mov byte ptr es:[bx],' '
; add bx,2
; loop sub1s
; pop es
; pop cx
; pop bx
; ret
; sub2:
; push bx
; push cx
; push es
; mov bx,0b800h
; mov es,bx
; mov bx,0
; mov cx,2000
; sub2s:
; and byte ptr es:[bx],11111000b
; or es:[bx],al
; add bx,2
; loop sub2s
; pop es
; pop cx
; pop bx
; ret
; sub3:
; push bx
; push cx
; push es
; mov bx,0b800h
; mov es,bx
; mov bx,0
; mov cx,2000
; sub3s:
; and byte ptr es:[bx],10001111b
; or es:[bx],al
; add bx,2
; loop sub3s
; pop es
; pop cx
; pop bx
; ret
; sub4:
; push cx
; push si
; push di
; push es
; push ds
; mov si,0b800h
; mov es,si
; mov ds,si
; mov si,160; ds:si 指向第n+1行
; mov di,0; es:di 指向第n行
; cld
; mov cx,24
; sub4s:
; push cx
; mov cx,160
; rep movsb
; pop cx
; loop sub4s
; mov cx,80
; mov si,0
; sub4s1:
; mov byte ptr [160*24+si],' '; 最后一行清空
; add si,2
; loop sub4s1
; pop ds
; pop es
; pop di
; pop si
; pop cx
; ret
; setscreenends:
; nop
; code ends
; end start
assume cs:code
code segment
do0:
push bx
push cx
push dx
push si
push di
push ds
push es
jmp short select
table dw sub1, sub2,sub3,sub4
select:
mov dl, al
cmp ah, 3
ja goiret ;判断传递的是否大于 3
mov bl, ah
mov bh, 0
add bx, bx ;根据ah中的功能号计算对应子程序的地址在table表中的偏移
call word ptr table[bx] ;调用对应的功能子程序
goiret: pop es
pop ds
pop di
pop si
pop dx
pop cx
pop bx
iret
;功能子程序1：清屏
sub1: mov ax, 0b800h
mov es, ax
mov di, 0
mov cx, 2000
sub1s:mov byte ptr es:[di], ' '
add di, 2
loop sub1s
ret
;功能子程序2：设置前景色
sub2: mov ax, 0b800h
mov es, ax
mov di, 1
mov cx, 2000
sub2s:and byte ptr es:[di], 11111000b
or es:[di], dl
add di, 2
loop sub2s
ret
;功能子程序3：设置背景色
sub3:
mov cl, 4
shl dl, cl
mov ax, 0b800h
mov es, ax
mov di, 1
mov cx, 2000
sub3s:and byte ptr es:[di], 10001111b
or es:[di], dl
add di, 2
loop sub3s
ret
;功能子程序4：向上滚动一行
sub4: mov ax, 0b800h
mov ds, ax
mov si, 160 ;ds:si指向第n+1行
mov es, ax ;es:di指向第n行
mov di, 0
cld
mov cx, 24 ;共复制24行
sub4s:push cx
mov cx, 160
rep movsb ;复制
pop cx
loop sub4s
mov cx, 80
mov di, 0
sub4d:mov byte ptr es:[160*24+di], ' ' ;最后一行清空
add di, 2
loop sub4d
ret
doends: nop
start:
mov ax, cs
mov ds, ax
mov si, offset do0 ;设置源地址
mov ax, 0
mov es, ax
mov di, 200h ;设置目标地址
cld ;df置零
mov cx, offset doends - offset do0
rep movsb ;把do0放到目标地址 0：200h
mov ax, 0
mov es, ax
mov word ptr es:[7ch*4], 0
mov word ptr es:[7ch*4+2], 20h ;设置中断向量表
;注意：此时 cs = 20h， ip = 0
mov ax, 4c00h
int 21h
code ends
end start
代码中注释的是课本中的代码，因为直接使用是有问题的。
-
问题1： table dw sub1……中sub1存放的应该是子程序的偏移地址，这个偏移地址是相对于中断程序入口的，而此时sub1中存放的是相对于安装程序入口的地址，中间隔着安装程序。所以应该将被安装代码放到code段标号start前边，这样相对地址直接是相对于do0。当中断例程被复制到0:200h段中，标号sub1等也是相对于该程序段的偏移地址。
-
在设置中断向量表的时候，
0：[7ch*4] ip内存单元中的值应该设置为0，
0: [7ch*4+2] cs内存单元中的值应该设置为 20h。
原因：这个虽然和一般设定
mov ax, 0 mov es, ax mov word ptr es:[7ch*4], 200h mov word ptr es:[7ch*4+2], 0是一样的，但是在执行程序中call word ptr table[bx]的过程中，只看cs，不看ip，所以cs中要包含ip的值。该段代码相当于是jmp cs:[table+bx]，当前的cs为0，ip为某个值，那么内存空间0:[table+bx]与我们所想的不是一个内存单元。如果按照第一种做法，此时cs:[table+bx], 是内存空间 20h:[table+bx], 是我们想得到的结果。