VST实例（7）拖拽（drag&drop）

1、拖拽操作需要用到的单元和函数

在讲拖拽操作之前先讲两个过程（procedure）：

• Moveto

procedure MoveTo(Source: PVirtualNode; Target: PVirtualNode; Mode: TVTNodeAttachMode; ChildrenOnly: Boolean); overload;

procedure MoveTo(Node: PVirtualNode; Tree: TBaseVirtualTree; Mode: TVTNodeAttachMode; ChildrenOnly: Boolean); overload;

将给定的节点（及其所有子节点）移动到目标节点处。源节点必须属于调用此MoveTo方法的树实例。Mode参数确定如何将源节点连接到目标节点。如果目标节点属于与源节点不同的树，则此方法可能涉及更改树的结构。

对于将节点转移至不同的树，可以使用带有树引用的变体，而无需首先确定其根节点。但是，只要目标虚拟树节点属于一棵树，也可以将其作为目标传递。所属树将自动确定，并且如果操作在同一棵树内进行，则采用优化的路径。在这种情况下，只需从旧位置断开源节点，重新连接到新位置即可。

• Copyto

function CopyTo(Source: PVirtualNode; Tree: TBaseVirtualTree; Mode: TVTNodeAttachMode; ChildrenOnly: Boolean): PVirtualNode; overload;

function CopyTo(Source: PVirtualNode; Target: PVirtualNode; Mode: TVTNodeAttachMode; ChildrenOnly: Boolean): PVirtualNode; overload;

拖拽操作可能需要用到上面的操作。

注意：如果要实现拖拽，还需要手动引用单元：Winapi.ActiveX。DELPHI可能不会自动帮你引用这个单元。

Treeoptions.autooptions如果包含了toautodeletemovednodes，则会在拖拽完成后，删除被拖拽的节点。

2、允许拖拽

树中的节点如果需要拖拽，需要在“ondragallowed”事件中允许。本程序只允许在单选且二级节点（机场）作为拖拽节点时进行拖拽，所以代码比较简单：

procedure TForm2.vstDragAllowed(Sender: TBaseVirtualTree; Node: PVirtualNode;
  Column: TColumnIndex; var Allowed: Boolean);
begin
   Allowed:=(Sender.GetNodeLevel(node)=1)
             and (Sender.SelectedCount=1);
end;

3、接收拖拽允许

当被拖拽的节点在目标上时，可以设置目标节点是否接收其拖拽。需要在“”事件中写代码。本程序的允许条件是①拖拽源来自VST。②目标节点是一级节点（LEVEL=0）。③目标节点不是源节点的父节点（拖入到同一个情报区下是没有任何意义的），代码如下：

procedure TForm2.vstDragOver(Sender: TBaseVirtualTree; Source: TObject;
  Shift: TShiftState; State: TDragState; Pt: TPoint; Mode: TDropMode;
  var Effect: Integer; var Accept: Boolean);
var node:PVirtualNode;
begin
   Accept:=Source=vst;
   node:=Sender.GetNodeAt(Pt.X,Pt.y);
   Accept:=(Sender.GetNodeLevel(node)=0) and Accept;
   accept:=Accept and (vst.FocusedNode.Parent<>node);
end;

4、实现拖拽

前面两部分，首先是允许被拖拽，然后在特定节点上，还需要获得接收拖拽的授权，在完成两项授权后，在事件“ondragdrop”中实现拖拽的实现。本程序的实现代码如下：

procedure TForm2.vstDragDrop(Sender: TBaseVirtualTree; Source: TObject;
  DataObject: IDataObject; Formats: TFormatArray; Shift: TShiftState;
  Pt: TPoint; var Effect: Integer; Mode: TDropMode);
var node1,node2:PVirtualNode; s:string;
begin
  node2:=Sender.DropTargetNode;
  node1:=vst.FocusedNode ;
  s:=Format('移动%s到%s',[pcodes(Sender.GetNodeData(node1))^.names,
                          pcodes(Sender.GetNodeData(node2))^.names   ]);
  ShowMessage(s);
  Sender.MoveTo(node1,node2,amAddChildLast,false );
end;

执行效果如图所示：

拖拽前

拖拽落下时，提示信息。

拖拽结束：

CYQQ被移动到CZUL情报区。当然程序中未对原始数据进行修改，只要你有需求，都可以在拖拽时根据自己的需求予以实现。

而且本程序没有使用到键盘，例如你可以实现在按着CTRL键的同时拖拽实现复制等等。

最后补充一点：dragdrop是可以多节点拖拽的，在多节点拖拽时，被拖拽的节点就是selectednodes。