前面写了如何快速读取一个JSON串,但只是针对简单的类型,如果JSON串中有数组该怎么办呢?
一、例子代码
先看下面的代码,读取一个学生的各科成绩。
procedure TForm6.Button1Click(Sender: TObject);
var
jsonstr:string;
jv:TJSONValue;
js:TJSONString;
ja:TJSONArray;
jo:TJSONObject;
I: Integer;
begin
jsonstr:=
'{' +
' "person": {' +
' "sex": "男",' +
' "name": "王小二",' +
' "score": [{' +
' "语文": 120' +
' },' +
' {' +
' "数学": 89' +
' },' +
' {' +
' "英语": 100' +
' }' +
' ]' +
' }' +
'}';
jv := TJSONValue.ParseJSONValue(jsonstr); //将JSON串转换为JSON对象,即TJSONValue对象
if jv <> nil then
begin
Log('姓名:' + jv.GetValue<TJSONValue>('person.name').Value); //直接读取节点值
Log('性别:' + jv.GetValue<TJSONValue>('person.sex').Value);
Log('成绩');
if jv.TryGetValue<TJSONArray>('person.score', ja) then //读取JSON对象中的数组对象
begin
for I := 0 to ja.Count - 1 do //循环数组对象
begin
jo := ja.A[I] as TJSONObject; //取数组元素对象
var pair:= jo.Pairs[0]; //取出Pair对象
var s1 := pair.JsonString.value; //读取Pair中键名
var s2 := pair.JsonValue.Value; //读取Pair中值
//var s2:=jo.Values[s1].Value; //也可以根据Pair的键名读取键值
Log(s1 + '=' + s2);
end;
end;
Log(jv.ToString); //输出:{"person":{"sex":"男","name":"王小二","score":[{"语文":120},{"数学":89},{"英语":100}]}}
log(jv.ToJSON); //输出:{"person":{"sex":"\u7537","name":"\u738B\u5C0F\u4E8C","score":[{"\u8BED\u6587":120},{"\u6570\u5B66":89},{"\u82F1\u8BED":100}]}}
end;
end;
运行后输出的结果:
二、代码解读
通过上面代码,重点在于如何解读JSON中的数组对象TJSONArray。
TJSONArray都是从TJSONValue继承而来,所以我们可以象正常一样,用TryGetValue方法从TJSONValue中读取一个TJSONArray对象。得到了TJSONArray对象,有两种方法取到每个元素值:
- TJSONArray.A[X]
- TJSONArray.Items[X]
这两种方式,都返回TJSONValue类型的对象。
循环一个TJSONArray,用到了TJSONArray.Count,即数据的长度,也可以用Size,但官方已经明确用Count取代了。从上面的代码中摘录出来:
if jv.TryGetValue<TJSONArray>('person.score', ja) then //读取JSON对象中的数组对象
begin
for I := 0 to ja.Count - 1 do //循环数组对象
begin
jo := ja.A[I] as TJSONObject; //取数组元素对象
//jo := ja.Items[I] as TJSONObject;//取数组元素对象的另一种写法
//...
end;
end;
循环一个TJSONArray的另一种写法,这种写法更简洁:
if jv.TryGetValue<TJSONArray>('person.score', ja) then //读取JSON对象中的数组对象
begin
var jva:TJSONValue;
for jva in ja do
begin
jo :=jva as TJSONObject;
//...
end;
end;
好了,本节,学会如何读取TJSONArray就好了。
标签:读取,对象,jv,TJsonArray,ja,JSON,TJSONArray,Delphi From: https://blog.51cto.com/kinglandsoft/5927723