1、jdk的安装：https://www.cnblogs.com/ljk2008/p/18324820。
2、jvm.dll:如果提示找不到JVM.dll需要在classpath、path中分别添加jvm.dll的路径。
3、用到三方库：https://github.com/aleroot/DelphiJNI.git。
4、JAVA类（CLASS、JAR）要放置在对应的文件夹内，如：package com.com1.com2;对应的目录应该是com\com1\com2
5、如java类中用的包中引用有其他jdk以外包，也应该对应放置到相应的目录
6、测试代码，以下内容来自：https://blog.csdn.net/dbyoung/article/details/89085406,感谢作者[email protected]。
现在很多SDK都提供了JAVA接口。但是没有Delphi接口。
没有办法只好曲线救国。我们可以通过 JNI 的方式在 Delphi10.3 中调用 Java 的函数。
第一步：创建 Java 虚拟机和运行环境
procedure TForm1.FormCreate(Sender: TObject);
var
Options: array [0 .. 4] of JavaVMOption;
VM_args: JavaVMInitArgs;
ErrCode: Integer;
begin
{ 创建 Java 虚拟机 }
FJavaVM := TJavaVM.Create(JNI_VERSION_1_8);
Options[0].optionString := PAnsiChar(AnsiString('-Djava.class.path=' + ExtractFilePath(ParamStr(0)) + 'classes'));
VM_args.version := JNI_VERSION_1_8;
VM_args.Options := @Options;
VM_args.nOptions := 1;
VM_args.ignoreUnrecognized := True;
ErrCode := FJavaVM.LoadVM(VM_args);
if ErrCode < 0 then
begin
MessageBox(Handle, 'Create Java VM Error', 'Delphi 10.3 调用 Java Class', MB_OK OR MB_ICONERROR);
Halt;
Exit;
end;
{ 创建 Java 虚拟机运行环境 }
FJavaEnv := TJNIEnv.Create(FJavaVM.Env);
if FJavaEnv = nil then
begin
MessageBox(Handle, 'Create Java Env Error', 'Delphi 10.3 调用 Java Class', MB_OK OR MB_ICONERROR);
Exit;
end;
end;
第二步：执行 Java 函数
procedure TForm1.btn1Click(Sender: TObject);
var
jcls : JClass;
strClass : UTF8String;
strMetod : UTF8String;
strSign : UTF8String;
strArg, strResult: string;
begin
{ 查询 Java 类名 }
strClass := 'com/test/javafordelphi/JavaClassForDelphiTest';
jcls := FJavaEnv.FindClass(strClass);
if jcls = nil then
begin
ShowMessage('cant find java class');
Exit;
end;
{ Java 函数名称、参数类型、参数 }
strMetod := 'goTest'; // 函数名称
strSign := 'String (String)'; // 参数类型，返回值类型
strArg := '123'; // 输入参数
{ 执行 Java 函数 }
strResult := CallMethod(FJavaEnv, jcls, strMetod, strSign, [strArg], True);
if strResult <> '' then
begin
MessageBox(Handle, PChar(Format('JavaClassForDelphiTest.goTest Result: %s', [strResult])), 'Delphi 10.3 调用 Java Class', MB_OK OR MB_ICONINFORMATION);
end;
end;
第三步：销毁虚拟机
procedure TForm1.FormDestroy(Sender: TObject);
begin
FJavaEnv.Free;
FJavaVM.DestroyJavaVM;
FJavaVM.Free;
end;
添加 JNI, JNIUtils 单元引用。
添加两个成员变量：
private
FJavaVM : TJavaVM;
FJavaEnv: TJNIEnv;
编译通过。
不要着急运行。先确认一下你是否安装了JAVA，并且系统搜索路径中是否包含 Java 的路径。
默认是(x86)：
C:\Program Files (x86)\Java\jdk1.8.0_202\bin
C:\Program Files (x86)\Java\jdk1.8.0_202\jre\bin\server
如果没有，将它们添加到 Windows 系统搜索路径中(环境变量：Path)。
执行。
效果图1
效果图2
完整代码，包含 jni 源代码代码，和2个DEMO源代码，可以从这里下载：
https://download.csdn.net/download/dbyoung/11096704
开发语言：
Delphi10.3
开发作者：
[email protected]
QQ群:101611228
开发时间：
2019-04-06