一键安装打印机程序

【亲测好用】自动安装打印机脚本

@echo off
rem 自动提权以管理员方式运行
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' EQU '5' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"

rem 打印显示
title xxxx  打印机一键安装
echo.
echo.
echo ------------------------------------------------
color 0C
echo 正在安装打印机....
echo 1. 如有弹窗点确定或允许。
echo 2. 安装完成后才可继续安装关闭此界面。
echo 3. 杀毒软件可能报毒，请点击允许，否则无法正常安装.
echo 4. 安装可能视电脑配置、网络影响，安装会比较久，请等待安装完成！
echo ------------------------------------------------
TIMEOUT /T 5
color 07

::本来写了判断电脑某路径下是否存在驱动，没有就去共享盘拷贝，后来有点小bug，懒得写了，直接全部覆盖拷贝，也就不到一秒的时间 - -
rem 复制驱动给本地
echo ====================================
echo.检测到您的电脑没有打印机驱动，正在为你下发打印机驱动。
echo ====================================
xcopy /Q /Y /E \\ip\Print_devices\  "C:\Program Files\"
::Program Files目录比较特殊，带空格。必须双引号！


rem 修改区
set print_name=xxx打印机
::打印机名称，本地用户可以看到的打印机名字
set print_IP=192.168.10.xxx
::打印机网络IP
set print_drive_dir=C:\Program Files\Software\PCL\amd64\Common\001\FF6NNAL.inf
::打印机驱动位置，这里是拷贝好了的
set print_drive_name=FF K509p for ApeosPort Print C5570 PCL 6
::系统要识别的打印机驱动名称，要在inf里面查
set print_area=xxx部
::没特殊异议，就最后公屏显示xxx打印机位置

rem 重启服务
net stop spooler>nul
net start spooler>nul


rem 删除重名打印机
powershell -Command "& {remove-printer -name %print_name%}"

cls

rem 添加驱动
C:\Windows\System32\pnputil.exe -i -a "%print_drive_dir%"
powershell -Command "& {Add-PrinterDriver -Name '%print_drive_name%'}"

rem 添加端口
::powershell -Command "& {Add-PrinterPort -Name 'IP_%print_IP%' -PrinterHostAddress '%print_IP%'}"

rem 添加打印机
powershell -Command "& {Add-Printer -Name %print_name% -DriverName '%print_drive_name%' -PortName IP_%print_IP%}"

rem 其他非关键
cls

echo.
echo.
echo.
echo ------------------------------------------------------------------
echo 打印机名：	%print_name%
echo 位置：		%print_area%
echo.
echo.
echo 安装已完成，如有问题请联系管理员。
echo ------------------------------------------------------------------

pause

大致的脚本就是这样子，很多东西都懒得改善，如果有问题可以联系我，共同研究，目前就是够用，该脚本也是借鉴(CV工程师)了网上的知识。侵删！